Kalender „Wichtige Termine“
27.02.2022 Termin X
06.03.2022 Termin Y
16.05.2022 Termin Z

property calendarName : "Business" 

on getDateRange()
    set today to (current date)
    set dateRangeStart to (today - 50 * days)
    set dateRangeEnd to (today)
    return {dateRangeStart, dateRangeEnd}
end getDateRange

on filterToDateRange(theStartDates, theEndDates, theSummaries, dateRangeStart, dateRangeEnd)
    set {eventDatesInRange, endDatesInRange, eventSummariesInRange} to {{}, {}, {}}
    repeat with i from 1 to (count theStartDates)
        set thisStartDate to item i of theStartDates
        if (not ((thisStartDate comes before dateRangeStart) or (thisStartDate comes after dateRangeEnd))) then
            set end of eventDatesInRange to thisStartDate
            set end of endDatesInRange to item i of theEndDates
            set end of eventSummariesInRange to item i of theSummaries
        end if
    end repeat    
    return {eventDatesInRange, endDatesInRange, eventSummariesInRange}
end filterToDateRange

on composeText(eventDatesInRange, endDatesInRange, eventSummariesInRange)
    set txt to ""
    set gap to linefeed
    set matchCount to (count eventDatesInRange)
    if (matchCount is 0) then return "No events found between the specfied dates."
    repeat with i from 1 to matchCount
        set txt to txt & item i of eventDatesInRange & ((";" & item i of endDatesInRange) & (";" & item i of eventSummariesInRange & gap))
    end repeat
    return text 1 thru -3 of txt
end composeText

on main()
    tell application "Calendar" to set {theStartDates, theEndDates, theSummaries} to {start date, end date, summary} of events of calendar calendarName
    set {dateRangeStart, dateRangeEnd} to getDateRange()
    set {eventDatesInRange, endDatesInRange, eventSummariesInRange} to filterToDateRange(theStartDates, theEndDates, theSummaries, dateRangeStart, dateRangeEnd)
    set txt to composeText(eventDatesInRange, endDatesInRange, eventSummariesInRange)
    set filePath to (path to desktop as text) & "Termine.csv"
    set fRef to (open for access file filePath with write permission)
    set eof fRef to 0
    write txt to fRef
    close access fRef
    display dialog "Data saved to file"
end main
main()