…

Ist das möglich?

set secondsIn2Days to 172800
tell application "Mail"
set theInbox to inbox
set dateToday to current date
set firstMessage to 1
set lastMessage to (get count of messages in theInbox)
repeat with thisMessage from lastMessage to firstMessage by -1
set currentMessage to message thisMessage of theInbox
set messageDate to date received of currentMessage
set timeDifference to dateToday - messageDate
if timeDifference ≥ secondsIn2Days then
set yearMonthBox to ((year of messageDate) as string) & space & ((month of messageDate) as string)
if not (exists mailbox yearMonthBox) then
make new mailbox with properties {name:yearMonthBox}
end if
move currentMessage to mailbox yearMonthBox
end if
end repeat
end tell

set yearMonthBox to ((year of messageDate) as string) & space & ((item (month of messageDate) of monthNames) as string)

chiller,
nope.
Kein sync von intelligenten oder lokalen Ordnern

https://discussions.apple.com/thread/3970800?start=0&tstart=0

set secondsIn2Days to 172800
tell application "Mail"
set theInbox to inbox
set Wolke to account "iCloud"
set dateToday to current date
set firstMessage to 1
set lastMessage to (get count of messages in theInbox)
repeat with thisMessage from lastMessage to firstMessage by -1
set currentMessage to message thisMessage of theInbox
set messageDate to date received of currentMessage
set timeDifference to dateToday - messageDate
if timeDifference ≥ secondsIn2Days then
set yearMonthBox to ((year of messageDate) as string) & space & ((month of messageDate) as string)
if not (exists mailbox yearMonthBox) then
set Postfach to make new mailbox with properties {name:yearMonthBox} at Wolke
end if
move currentMessage to mailbox Postfach
end if
end repeat
end tell

Mit "intelligenten Postfächern" wird nicht verschoben, nur gespiegelt.

Doch!

Doch!
…

Ja. Syncen eines iCloud Postfachs (Ordner) funktioniert natürlich.

Was aber machst Du mit "nicht Mail Accounts"?

set secondsIn2Days to days * 2
set monthNames to {"Januar", "Februar", "März", "April", "May", "Juni", "Juli", "August", "September", "Oktober", "November", "Dezember"}
tell application "Mail"
set theInbox to inbox
set Wolke to account "iCloud"
set dateToday to current date
set firstMessage to 1
set lastMessage to (get count of messages in theInbox)
repeat with thisMessage from lastMessage to firstMessage by -1
set currentMessage to message thisMessage of theInbox
set messageDate to date received of currentMessage
set timeDifference to dateToday - messageDate
if timeDifference ≥ secondsIn2Days then
set yearMonthBox to ((year of messageDate) as string) & space & ((item (month of messageDate) of monthNames) as string)
if not (exists mailbox yearMonthBox of Wolke) then
make new mailbox with properties {name:yearMonthBox} at Wolke
end if
if (read status of currentMessage) is true then
move currentMessage to mailbox yearMonthBox
end if
end if
end repeat
end tell

set days2 to 2
set dateToday to current date
set monthNames to {"Januar", "Februar", "März", "April", "May", "Juni", "Juli", "August", "September", "Oktober", "November", "Dezember"}
tell application "Mail"
set theCloud to account "maeuschen@mac.com"
set unreadMessages to ¬
(get every message of mailbox "INBOX" of theCloud whose read status is true)
repeat with aMessage in unreadMessages
set messageDate to date received of aMessage
set timeDifference to (dateToday - messageDate) / days
if timeDifference ≥ days2 then
set yearBox to ((year of messageDate) as string)
set monthBox to ((item (month of messageDate) of monthNames) as string)

if not (exists mailbox yearBox of theCloud) then ¬
make new mailbox with properties {name:yearBox} at theCloud

if not (exists mailbox monthBox of mailbox yearBox of theCloud) then ¬
make new mailbox with properties {name:yearBox & "/" & monthBox} at theCloud

move aMessage to mailbox monthBox of mailbox yearBox of theCloud
end if
end repeat
end tell