use AppleScript version "2.4" -- Yosemite (10.10) or later
use scripting additions

on open location theURL
    if user locale of (system info) does not start with "de" then display alert "Das Skript funktioniert in der Form nur mit deutschen Systemen." buttons {"Abbrechen"} cancel button 1
    set urlComponents to stringSplit(theURL, "/")
    set theScheme to item 1 of urlComponents
    set theYear to item 3 of urlComponents
    set theMonth to item 4 of urlComponents
    set theDay to item 5 of urlComponents
    try
        set theView to item 6 of urlComponents
    on error
        set theView to "day"
    end try
    tell application "Calendar"
        if theView is in {"dayview", "day", "d"} then switch view to day view
        if theView is in {"monthview", "month", "m"} then switch view to month view
        if theView is in {"weekview", "week", "w"} then switch view to week view
        view calendar at date (theDay & "/" & theMonth & "/" & theYear)
    end tell
end open location

on run
    if name of current application is "Script Debugger" or name of current application is "Script Editor" then
        open location "gocal://2020/12/21/w"
    else
        display alert "GoCal Helper" message "Mit einem Aufruf wie „gocal://2022/12/24/day“ springst du in der Kalender-App zu einem bestimmten Datum. Optional kannst du hinter dem Tag noch die Art der Ansicht (day, week, month) angeben."
    end if
end run

on stringSplit(subjectStr, splitStr)
    if subjectStr does not contain splitStr then return subjectStr
    set orgDelims to text item delimiters of AppleScript
    set text item delimiters of AppleScript to splitStr
    set subjectStr to text items of subjectStr
    set text item delimiters of AppleScript to orgDelims
    return subjectStr
end stringSplit

shortcuts://run-shortcut?name=cal&input=%7B%22type%22:%22event%22,%22title%22:%22Test%22,%22date%22:%2220.04.2023,%2009:00%22%7D

tell application "Calendar" to switch view to day view